The Interactive Image (Fall 2005)

Code

// based off of code by Zachary Lieberman from "Making Things Move" example 02 _ 06


int numFish = 50;


Fish school[];          // declare class (who moves)

//---------------------------------------------------------
void setup(){

  size(600,400);

  school = new Fish[numFish];   //allocation
  for (int i=0; i<numFish; i++){
    school[i] = new Fish();  //construction

  }
}

//---------------------------------------------------------
void draw(){

  background(15,35,75);

  for (int i=0; i<numFish; i++){

    // set attraction properties
    school[i].attraction();

    // draw fish
    school[i].render();

  }
}


//-----------------------------------------------------------------

class Fish {


  float x,y,w,h;
  float xOld, yOld;                    // snapShots of prev position;
  float angle;                         // based on my last position, what is my angle?

  float blurRate;                      // controls the speed at wich we "catch" the target
  float one_m_blurRate;                // one minus blur rate


//-----------------------------------------------------------------
  Fish (){

    w = 30;
    h = 15;
    x = random(0, width);
    y = random(0, height);

    blurRate = 0.98;
    one_m_blurRate = 1 - blurRate;
  }

//-----------------------------------------------------------------
  void attraction(){

    if (abs (mouseX-x) <100 && abs (mouseY - y) <100){

      float catch_x = mouseX;
      float catch_y = mouseY;

      x = blurRate * x + one_m_blurRate * catch_x;
      y = blurRate * y + one_m_blurRate * catch_y;

      // now calculate angle:
      float xDiff = x - xOld;      
      float yDiff = y - yOld;  
      angle = (float)atan2(yDiff, xDiff);



      // take snapshot:
      xOld = x;
      yOld = y;


    }
  }


//-----------------------------------------------------------------
  void render(){


    pushMatrix(); 
    translate(x,y);
    rotate(angle);  
    ellipseMode(CENTER);        // use x y as center, not corner
    noStroke();
    fill(249, 237, 237);            
    ellipse(0,0,w,h);


    popMatrix();
  }

}