// run magnet simulation with gravity, drag, etc.


Point history[];
int historyLen = 500;
int curPoint = 0;
boolean historyDone;

Blob billy;

void setup(){
  size(500,600);
  background(255);
  billy = new Blob(40, 200);
  billy.vx = 6.0;

  historyDone = false;
  history = new Point[historyLen];
  for (int i=0; i<historyLen; i++){
    history[i] = new Point();
  }
}

class Point {
  float x;
  float y;
}

void loop(){
  background(255);
  
  updateStuff();
  drawStuff();
  
  storeHistory();
  drawHistory();
  
}

void storeHistory(){
  if (curPoint < historyLen){
    history[curPoint].x = billy.px;
    history[curPoint].y = billy.py;
    curPoint++;
  } 
}

void drawHistory(){

    stroke(255,0,0);
    float x0,y0,x1,y1;
    for (int i=1; i<curPoint; i++){
      x0 = history[i-1].x;
      y0 = history[i-1].y;
      x1 = history[i].x;
      y1 = history[i].y;
      line (x0,y0, x1,y1);
    }
}



//-------------------------------------
void updateStuff(){
  billy.applyGravityForce();
  billy.applyDragForce();
  billy.update();
}

//-------------------------------------
void drawStuff(){
  billy.render();
}

void mouseReleased(){
  background(255);
  billy.px = mouseX;
  billy.py = mouseY;
  billy.vx = random(0,6);
  billy.vy = 0;
  
  curPoint = 0;
  historyDone = false;
}
void mousePressed(){
  background(255);
}

//-------------------------
final float GRAVITY_X = 0;
final float GRAVITY_Y = 1.0;
final float FRICTION = 0.01;
final float COLLISION_FRICTION = 0.90;

class PhysicalThing {
  float px, py;
  float vx, vy;
 

  void applyGravityForce(){
    vx += GRAVITY_X;
    vy += GRAVITY_Y;
  }

  void applyDragForce(){
    float fdragx = vx * FRICTION * -1.0;
    float fdragy = vy * FRICTION * -1.0;
    vx += fdragx;
    vy += fdragy;
  }

  void handleGroundCollision(){

    if ((py+vy) >= height){
      vy = 0 - vy;
      vy *= COLLISION_FRICTION;
    }
  }

  void update(){
    handleGroundCollision();
    px += vx;
    py += vy;

    while (px > width){
      px -= width;
    }
    while (px < 0){
      px += width;
    }

  }
}

//-------------------------
class Blob extends PhysicalThing {
  float R; //radius
   
  Blob(float x, float y){
    px = x; py = y;
    vx = vy = 0;
    R = 8;
  }

  void render(){
    ellipseMode(CENTER_DIAMETER);
    stroke(0,0,0);
    fill(255, 200, 200);

    push();
    translate(px, py);

    float ang = atan2 (vy, vx);
    rotateZ(ang + HALF_PI);

    float sqx =  (R*2) + abs(vx) * 0.5;
    float sqy =  (R*2) + abs(vy) * 0.5;
    ellipse(0, 0, sqx, sqy);
    pop();
  }

}